2.4 Вычисление термодинамических активностей компонентов бронзы БрБ2 при 25°С

Для расчёта активностей нужно воспользоваться формулами (2.1), (2.2) и (2.3). Мольные доли компонентов рассчитываются из известных массовых долей.

(2.22)

Здесь ω – массовая доля, M – молярная масса компонента.

Данные о значениях энергий смешения системы Cu – Ni при 25°С получены из таблицы 2.4, для систем Be – Cu и Be – Ni они предоставлены предшествующими исследователями:

(2.23)

(2.24)

(2.25)

(2.26)

Расчёты проведены с помощью компьютерной программы, текст которой приведён в приложении В.

Получены следующие результаты:

(2.27)

(2.28)

(2.29)

Выводы

По результатам данной работы были установлены температурные зависимости энергий смешения твёрдого раствора системы Cu – Ni. Их правильность была доказана тем, что купол расслаивания твёрдого раствора, рассчитанный на основании этих зависимостей, практически совпал с экспериментальным. Это позволило экстраполировать купол расслаивания и зависимости Q=f(T) до области комнатных температур.

Были определены активности меди и никеля в твёрдом растворе при 25°С в зависимости от мольного содержания компонентов. При некоторых содержаниях активности оказались больше единицы. Это свидетельствует о расслоении твёрдого раствора на несколько фаз, возможно, интерметаллических.

Наконец, были определены активности компонентов бронзы БрБ2, содержащей бериллий, медь и никель. Эта бронза представляет из себя переохлаждённый раствор и является метастабильной. Это подтверждается тем, что активность бериллия оказалась больше единицы. Происходит выпадение бериллия в отдельную фазу из раствора, или образование интерметаллидов.

Рассчитанные активности будут использованы в дальнейшем для моделирования термодинамических свойств бериллиевой бронзы.

Приложения

Приложение А

Программа для расчёта энергий смешения состоит из двух частей. Первая часть – дополнительная, она готовит файл данных с координатами купола расслаивания, снятыми с диаграммы состояния. Текст приведён ниже:

10 OPEN "source.txt" FOR OUTPUT AS #1

20 FOR i = 1 TO 6

30 READ t, x, n

40 REM 't'-температура, 'x' и 'n'-мольные доли меди в двух фазах

50 PRINT #1, (t + 273), x, n

60 NEXT i

70 CLOSE #1

80 DATA 200, 0.650, 0.013

90 DATA 225, 0.633, 0.027

100 DATA 250, 0.580, 0.053

110 DATA 275, 0.513, 0.073

120 DATA 300, 0.467, 0.113

130 DATA 325, 0.387, 0.187

140 END

Вторая часть – основная, именно она рассчитывает энергии смешения и выводит их в файл данных.

10 CLS : REM программа для расчёта энергий смешения

20 DIM t(6), x(6), n(6), q(6), r(6)

30 REM 't'-температура,'x' и 'n'-мольные доли

40 REM 'q' и 'r'-члены разложенной в ряд Тейлора энергии смешения

50 OPEN "source.txt" FOR INPUT AS #1

60 FOR i = 1 TO 6: REM ввод исходных данных

70 INPUT #1, t(i), x(i), n(i)

80 NEXT i

90 CLOSE #1

100 OPEN "Q.txt" FOR OUTPUT AS #1

110 FOR i = 1 TO 6: REM расчёт Q12(1) и Q12(2)

120 LET t = t(i): LET x = x(i): LET n = n(i)

130 LET a = 8.3144 * t * LOG((1 - x) / (1 - n)) * ((1 - 2 * n) * (1 - n) ^ 2 - (1 - 2 * x) * (1 - x) ^ 2)

140 LET b = 8.3144 * t * LOG(x / n) * (x ^ 2 * (2 - 2 * x) - n ^ 2 * (2 - 2 * n))

150 LET c = (x ^ 2 * (2 * x - 1) - n ^ 2 * (2 * n - 1)) * ((1 - 2 * n) * (1 - n) ^ 2 - (1 - 2 * x) * (1 - x) ^ 2)

160 LET d = (2 * x * (1 - x) ^ 2 - 2 * n * (1 - n) ^ 2) * (x ^ 2 * (2 - 2 * x) - n ^ 2 * (2 - 2 * n))

170 LET q = -(a + b) / (c + d): REM q=Q12(1)

180 LET e = 8.3144 * t * LOG(x / n) + q * (2 * x * (1 - x) ^ 2 - 2 * n * (1 - n) ^ 2)

190 LET f = ((1 - 2 * n) * (1 - n) ^ 2 - (1 - 2 * x) * (1 - x) ^ 2)

200 LET r = e / f: REM r=Q12(2)

210 LET q(i) = q

220 LET r(i) = r

230 PRINT #1, t(i), q(i), r(i)

240 NEXT i

250 CLOSE #1

260 END

Приложение Б

Текст программы для расчёта активностей в двойной системе приведён ниже:

10 CLS : REM программа для расчёта активностей меди и никеля

20 LET r = 8.3144: REM универсальная газовая константа

30 LET t = 298: REM температура 25 С = 298 К

40 LET q1 = -16369.02: REM Q12(1) при 25 С

50 LET q2 = 24136.67: REM Q12(2) при 25 С

60 OPEN "activ.txt" FOR OUTPUT AS #1

70 PRINT #1, "x1", "x2", "a1", "a2"

80 FOR x = .01 TO .99 STEP .01

90 REM x = x1 - мольная доля меди

100 LET y = 1 - x: REM y = x2 - мольная доля никеля

110 LET z1 = r * t * LOG(x) + (y ^ 2) * (2 * x * q1 + (1 - 2 * x) * q2)

120 LET z2 = r * t * LOG(y) + (x ^ 2) * ((1 - 2 * y) * q1 + 2 * y * q2)

130 REM z1 = RTln a1 и z2 = RTln a2

140 LET a1 = EXP(z1 / (r * t)): REM активность меди

150 LET a2 = EXP(z2 / (r * t)): REM активность никеля

160 PRINT #1, x, y, a1, a2

170 NEXT x

180 CLOSE #1

190 END

Приложение В

Текст программы для расчёта активностей в тройной системе приведён ниже:

10 CLS

20 LET r = 8.3144: REM r - универсальная газовая постоянная

30 LET t = 298: REM t - температура, 25 С = 298 К

40 LET rt = r * t: REM RT

50 REM 1 - Cu, 2 - Ni, 3 - Be

60 LET x1 = .868: LET x2 = .005: LET x3 = .127: REM мольные доли в бронзе БрБ2

70 DIM q1(3, 3): DIM q2(3, 3)

80 REM элемент массива q1(i,j) - это Qij(1) при температуре t

90 REM элемент массива q2(i,j) - это Qij(2) при температуре t

100 LET q1(1, 2) = 76.812 * t - 39259

110 LET q2(1, 2) = -51.085 * t + 39360

120 LET q1(1, 3) = -10.55 * t + 24080

130 LET q2(1, 3) = q1(1, 3)

140 LET q1(2, 3) = 18.25 * t - 34260

150 LET q2(2, 3) = q1(2, 3)

160 REM вычисление z1=RTln a1

170 LET z1 = rt * LOG(x1) + 2 * x1 * x2 * (1 - x1) * q1(1, 2) + (x2 ^ 2) * (1 - 2 * x1) * q2(1, 2)

180 LET z1 = z1 + 2 * x1 * x3 * (1 - x1) * q1(1, 3) + (x3 ^ 2) * (1 - 2 * x1) * q2(1, 3)

190 LET z1 = z1 - 2 * x2 * x2 * x3 * q1(2, 3) - 2 * x2 * x3 * x3 * q2(2, 3)

200 REM вычисление z2=RTln a2

210 LET z2 = rt * LOG(x2) + 2 * x1 * x2 * (1 - x2) * q2(1, 2) + (x1 ^ 2) * (1 - 2 * x2) * q1(1, 2)

220 LET z2 = z2 + 2 * x2 * x3 * (1 - x2) * q1(2, 3) + (x3 ^ 2) * (1 - 2 * x2) * q2(2, 3)

230 LET z2 = z2 - 2 * x1 * x1 * x3 * q1(1, 3) - 2 * x1 * x3 * x3 * q2(1, 3)

240 REM вычисление z3=RTln a3

250 LET z3 = rt * LOG(x3) + 2 * x1 * x3 * (1 - x3) * q2(1, 3) + (x1 ^ 2) * (1 - 2 * x3) * q1(1, 3)

260 LET z3 = z3 + 2 * x2 * x3 * (1 - x3) * q2(2, 3) + (x2 ^ 2) * (1 - 2 * x3) * q1(2, 3)